[BatchScript] Cài đặt Offline tập tin MSU hoặc CAB

Thông thường việc update thường do công cụ Windows Update đảm nhiệm, tuy nhiên có rất nhiều trường hợp người này nhận được update còn người khác thì không...Những trường hợp như vậy thì đây sẽ là cách tối ưu nhất cho chúng ta

Tập tin update thường được MS phát hành với phần mở rộng là .msu hoặc .cab với 1 số file msu ta có thể đúp chuột vào để nó tự cài đặt còn file cab thì không.

Để thuận tiện hơn mình đã soạn thảo ra 1 file .bat hỗ trợ cài đặt trực tiếp, bạn sẽ không cần nhớ những dòng lệnh dài dòng nữa

B1: Mở RUN gõ notepad

B2: Bạn copy nội dụng này vào

@echo off
REM Make by Hoang Hung
title Install hotfix MSU_CAB for Windows 7-8-8.1-10
mode con cols=120 lines=20
color 0f
pushd %~dp0
::------------------------------------------------------------------------------------------------------------
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if "%errorlevel%" NEQ "0" (
 echo: Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
 echo: UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
 "%temp%\getadmin.vbs" & exit 
)
if exist "%temp%\getadmin.vbs" del /f /q "%temp%\getadmin.vbs"
echo ====================================================================================================================&echo.
echo                                                Made by Hoang Hung&echo.
echo ====================================================================================================================&echo.
echo                                        [1]: Install ALL CAB files in folder&echo.
echo                                        [2]: Install ALL MSU files in folder&echo.
echo                                        [X]: EXIT&echo.
echo ====================================================================================================================&echo.
CHOICE /C 12X /M "Your Choice: "
if errorlevel == 3 EXIT
if errorlevel == 2 goto:msufile
if errorlevel == 1 goto:cabfile
::------------------------------------------------------------------------------------------------------------
:cabfile
cls
for /f %%A in ('dir /b *.cab') do (
cls & echo.
echo == Installing Updates == "%%A" ...
Dism.exe /Online /Add-Package /PackagePath:%%A /NoRestart
timeout 4 >nul
)
echo. & echo == Updates installed == & echo.
echo == Please reboot your machine to complete these updates...== & echo.
pause
exit
::------------------------------------------------------------------------------------------------------------
:msufile
cls
sc config wuauserv start= auto >nul 2>&1
net start wuauserv >nul 2>&1
for /f %%A in ('dir /b *.msu') do (
echo.
echo == Installing Updates == "%%A" ...
"%SystemRoot%\System32\wusa.exe" %%A /quiet /norestart
)
echo. & echo == Updates installed == & echo.
echo == Please reboot your machine to complete these updates...== & echo.
pause
exit

B4 Bạn Ctrl S và lưu với tên ví dụ install.bat và lưu nó cùng thư mục với file msu hoặc cab đã tải về

B5: Bạn chạy file bat và nhấn 1 để cài tất cả file cab trong thư mục hiện tại hoặc 2 cho file msu

Sau khi cài đặt hoàn tất tiến hành khởi động lại máy để quá trình cài hoàn thành

Hưng Hoàng Văn